Option Explicit
Dim Store, Certificates, Certificate, binCert, binCertStr, Utils
Const CAPICOM_CURRENT_USER_STORE = 2
Const CAPICOM_CERTIFICATE_FIND_SUBJECT_NAME = 1
Const CAPICOM_STORE_OPEN_READ_ONLY = 0
Const SubjectName = "Mitch"
Const ForReading = 1, ForWriting = 2

Set Store = CreateObject("CAPICOM.Store")
Store.Open CAPICOM_CURRENT_USER_STORE, "MY" ,CAPICOM_STORE_OPEN_READ_ONLY     'Open store for read
Set Certificates = Store.Certificates.Find(CAPICOM_CERTIFICATE_FIND_SUBJECT_NAME, SubjectName, 0)
If Certificates.Count >0 Then
   For Each Certificate in Certificates
    Certificate.display()
   Next
binCertStr = Certificates(1).export(1)   'export first cert as binary-encoded string
 Else
  WScript.Echo "No certificates had SubjectName with substring matching """ & SubjectName & """"
End If
Set Certificates = Nothing
Set Store = Nothing

'-----  Approach using CAPICOM 2 utils and ADODB.Stream -----
 'Set Utils = CreateObject("CAPICOM.Utilities")
 'binCert = Utils.BinaryStringToByteArray(binCertStr)
 'SaveBinFile "outtest.cer", binCert

'----- Approach using Java moniker class  ------
 SaveBinaryJava "outtest.cer", binCertStr


'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'
' SaveBinFile
'
' Save binary array to FileName.
'
Sub SaveBinFile (FileName, Binarray)
  Dim oStream
  Const adSaveCreateOverWrite = 2
  Const adTypeBinary = 1
  Const adModeReadWrite = 3 
  Set oStream = WScript.CreateObject("ADODB.Stream")
  oStream.type = adTypeBinary
  oStream.mode = adModeReadWrite
  oStream.Open
  oStream.write Binarray
  oStream.SaveToFile FileName, adSaveCreateOverWrite
  oStream.Close
  Set oStream = nothing
End Sub


''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'
' SaveBinaryJava
' Uses Java moniker and FileOutputUtil.class
' Saves binary-packed strings as binary file.
' Saves regular strings as UNICODE (2 bytes/character)

Sub SaveBinaryJava (FileName, StringBuffer)
dim oJFile, i
set oJFile = GetObject("java:FileOutputUtil")
oJFile.openFile(FileName)
 For i=1 to Lenb(StringBuffer)
   oJFile.writebyte(Ascb(Midb(StringBuffer,I,1)))
 Next
oJFile.closeFile()
End Sub